Add bt-agent

machines/AMD-Workstation/default.nix

@@ -36,6 +36,11 @@
 
   environment.sessionVariables.WINEPREFIX = "/home/balsoft/.local/share/wineprefixes/default";
 
+  services.bt-agent = {
+    enable = true;
+    capability = "NoInputNoOutput";
+  };
+
   persist = {
     enable = true;
     cache.clean.enable = false; # Scary...

modules/bt-agent.nix

@@ -0,0 +1,38 @@
+{ config, pkgs, lib, ... }: {
+  options.services.bt-agent = with lib; {
+    enable = mkEnableOption "Bluetooth authentication agent";
+    package = mkOption {
+      default = pkgs.bluez-tools;
+      type = types.package;
+    };
+    capability = mkOption {
+      default = "DisplayYesNo";
+      description = "Agent capability";
+      type = types.enum [
+        "DisplayOnly"
+        "DisplayYesNo"
+        "KeyboardOnly"
+        "NoInputNoOutput"
+      ];
+    };
+    pinFile = mkOption {
+      default = null;
+      type = types.nullOr types.path;
+      description = "Path to the PIN's file";
+    };
+  };
+  config = let
+    cfg = config.services.bt-agent;
+    args = [ "--capability=${cfg.capability}" ]
+      ++ lib.optional (!isNull cfg.pinFile) "--pin=${cfg.pinFile}";
+  in lib.mkIf cfg.enable {
+    systemd.services.bt-agent = {
+      path = [ cfg.package ];
+      serviceConfig.Type = "forking";
+      serviceConfig.KillSignal = "SIGKILL";
+      script = "bt-agent -d ${lib.escapeShellArgs args}";
+      wantedBy = [ "bluetooth.target" ];
+      after = [ "bluetooth.service" ];
+    };
+  };
+}

roles/base.nix

@@ -7,6 +7,7 @@
     secrets
     secrets-envsubst
     persist
+    bt-agent
 
 
     # PROFILES