ligo/nix/ocaml-overlay.nix

{ sources ? import ./sources.nix, version ? "git" }:
self: super:
let lib = import ./lib.nix self;
in {
  ocamlPackages = super.ocaml-ng.ocamlPackages_4_07.overrideScope'
    (builtins.foldl' self.lib.composeExtensions (_: _: { }) [
      (lib.traverseOPAMRepo' sources.opam-repository)
      (lib.traverseOPAMRepo sources.tezos-opam-repository)
      (lib.callOPAMPackage)
      (oself: osuper:
        with oself; {
          ocamlfind = findlib;
          lwt = lwt4;
          bigstring = osuper.bigstring.overrideAttrs (_: { doCheck = false; });
          xmldiff =
            osuper.xmldiff.overrideAttrs (_: { src = sources.xmldiff; });
          ipaddr = osuper.ipaddr.versions."4.0.0";
          conduit = osuper.conduit.versions."2.1.0";
          conduit-lwt-unix = osuper.conduit-lwt-unix.versions."2.0.2";
          cohttp-lwt-unix = osuper.cohttp-lwt-unix.versions."2.4.0";
          cohttp-lwt = osuper.cohttp-lwt.versions."2.4.0";
          macaddr = osuper.macaddr.versions."4.0.0";
          ocaml-migrate-parsetree =
            osuper.ocaml-migrate-parsetree.versions."1.4.0";
          ppx_tools_versioned = osuper.ppx_tools_versioned.versions."5.2.3";
          tezos-protocol-compiler = osuper.tezos-protocol-compiler.overrideAttrs
            (oa: {
              buildInputs = oa.buildInputs ++ [ oself.pprint ];
              postInstall =
                "ln -s $out/lib/ocaml/*/site-lib/tezos-protocol-compiler/* $out";
            });
          conf-gmp = self.gmp;
          conf-libev = self.libev;
          conf-hidapi = self.hidapi;
          conf-pkg-config = self.pkg-config;

          tezos-protocol-006-PsCARTHA =
            oself.callOPAMPackage ../vendors/ligo-utils/tezos-protocol-alpha {
              pname = "tezos-protocol-006-PsCARTHA";
              version = "0.0.0";
              opamFile = "tezos-protocol-006-PsCARTHA.opam";
            } { };

          tezos-protocol-006-PsCARTHA-parameters = oself.callOPAMPackage
            ../vendors/ligo-utils/tezos-protocol-alpha-parameters {
              pname = "tezos-protocol-006-PsCARTHA-parameters";
              version = "0.0.0";
            } { };

          tezos-utils =
            oself.callOPAMPackage ../vendors/ligo-utils/tezos-utils {
              pname = "tezos-utils";
              version = "0.1";
            } { };

          proto-alpha-utils =
            oself.callOPAMPackage ../vendors/ligo-utils/proto-alpha-utils {
              pname = "proto-alpha-utils";
              version = "0.1";
              extraBuildInputs =
                [ oself.tezos-protocol-006-PsCARTHA-parameters ];
            } { };

          simple-utils =
            oself.callOPAMPackage ../vendors/ligo-utils/simple-utils {
              pname = "simple-utils";
              version = "0.1";
            } { };

          tezos-memory-proto-alpha =
            oself.callOPAMPackage ../vendors/ligo-utils/memory-proto-alpha {
              pname = "tezos-memory-proto-alpha";
              version = "0.0.0";
            } { };

          michelson-parser = oself.callOPAMPackage
            ../vendors/ligo-utils/tezos-utils/michelson-parser {
              pname = "michelson-parser";
              version = "0.0.0";
            } { ocamlfind = oself.findlib; };

          UnionFind = oself.callOPAMPackage ../vendors/UnionFind rec {
            pname = "UnionFind";
            version = "master";
            buildPhase = "echo ${version} > Version.ml; dune build -p ${pname}";
          } { };

          ligo = oself.callOPAMPackage ../. {
            version = "0.1";
            extraBuildInputs = with oself; [ ppx_tools_versioned getopt self.getopt UnionFind ];
          } { };
        })
    ]);
}